home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Night Owl 9
/
Night Owl CD-ROM (NOPV9) (Night Owl Publisher) (1993).ISO
/
015a
/
sutl.zip
/
SOUNDER.BAS
< prev
next >
Wrap
BASIC Source File
|
1993-03-01
|
2KB
|
54 lines
100 ' SOUNDER.BAS -- Paul Somerson
110 ' Creates sample odd sounds
120 ' (c) 1987 Ziff Communications Co.
130 DEFINT A-Z
140 CLS:PRINT "Enter a number (0-9) or Esc to quit:"
150 I$=INKEY$:IF I$="" THEN 150
160 IF I$=CHR$(27) THEN END
170 IF INSTR("0123456789",I$)=0 THEN 150
180 ON VAL(I$)+1 GOSUB 210,250,290,330,370,410,450,490,530,570
190 GOTO 150
200 ' --- SOUND0 ---
210 FOR A=1 TO 10:FOR B=1 TO 1900 STEP 600
220 SOUND 3000-B, .33
230 NEXT:NEXT:RETURN
240 ' --- SOUND1 ---
250 FOR A=1 TO 10:FOR B=45 TO 900 STEP 300
260 SOUND 99+B, .33
270 NEXT:NEXT:RETURN
280 ' --- SOUND2 ---
290 FOR A=1 TO 5:FOR B=450 TO 1 STEP -80
300 SOUND 99+B, .3
310 NEXT:NEXT:RETURN
320 ' --- SOUND3 ---
330 FOR A=1 TO 10:FOR B=1 TO 300 STEP 50
340 SOUND 200+B, .34
350 NEXT:NEXT:RETURN
360 ' --- SOUND4 ---
370 FOR A=1 TO 15:FOR B=1 TO 200 STEP 80
380 SOUND 800+B, .1
390 NEXT:NEXT:RETURN
400 ' --- SOUND5 ---
410 FOR A=1 TO 15:FOR B=1 TO 450 STEP 200
420 SOUND 400+B, .3
430 NEXT:NEXT:RETURN
440 ' --- SOUND6 ---
450 FOR A=1 TO 200:OUT 66,0:OUT 66,0
460 OUT 97,(INP(97) OR 3)
470 NEXT:SOUND 37,0:RETURN
480 ' --- SOUND7 ---
490 FOR A=0 TO 250:OUT 66,A:OUT 66,A
500 OUT 97,(INP(97) OR 3)
510 NEXT A:SOUND 37,0:RETURN
520 ' --- SOUND8 ---
530 FOR A=250 TO 0 STEP -1:
540 OUT 66,A:OUT 66,A:OUT 97,(INP(97) OR 3)
550 NEXT A:SOUND 37,0:RETURN
560 ' --- SOUND9 ---
570 FOR B=1 TO 10:FOR A=40 TO 0 STEP -1
580 OUT 66,A:OUT 66,A:OUT 97,(INP(97) OR 3)
590 NEXT A:SOUND 37,0:NEXT
600 FOR B=1 TO 15:FOR A=0 TO 26
610 OUT 66,A:OUT 66,A:OUT 97,(INP(97) OR 3)
620 NEXT A:SOUND 37,0:NEXT:RETURN